Forums Développement Multimédia

Aller au contenu

Problème sur le tutoriel "Créer un diaporama en ActionScript 3"

CODE Actionscript

5 réponses à ce sujet

#1 cyrilou

    Ceinture Marron

  • Members
  • PipPipPipPipPipPip
  • 125 messages

Posté 21 November 2008 - 18:16 PM

Bonjour,

Comme je débute en AS3 (avec des notions et un bon niveau AS2 quand meme) et que je dois réaliser un diaporama en AS3 pour un client, je voulais commencer mon projet dans les règles de l'art pour ensuite avoir les bonnes bases dans ce langage.
J'ai donc suivi scrupuleusement étape par étape le très bon tutoriel Créer un diaporama en ActionScript 3.
J'ai réussi à publier le fichier après corrigé 2-3 trucs et ajouté les bibliothèques manquante jusqu'au moment ou plus aucune erreur de compilation ne s'affichait (hallelujah!!) mais, plus grave, une erreur en sortie incompréhensible pour moi qui me laisse impuissant :
Citation
TypeError: Error #1088: Le marquage du document après l'élément root doit être composé correctement.
at Diaporama/loadImagesPathCompleted()
at flash.events::EventDispatcher/dispatchEventFunction()
at flash.events::EventDispatcher/dispatchEvent()
at flash.net::URLLoader/onComplete()

Voici mon code:

Action Script

//from http://wiki.mediabox.fr/tutoriaux/flash/diaporama_as3

package {
import NextButton;
import PreviousButton;

import flash.display.Shape;
import flash.display.Sprite;
import flash.display.Loader;
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.geom.*;
import flash.events.*;
import flash.net.*;
import flash.text.*;
import flash.utils.Timer;

public class Diaporama extends Sprite
{
//Attributs
private var nextButton:NextButton;
private var previousButton:PreviousButton;
private var conteneurVignettes:Sprite;
private var masqueVignettes:Sprite;
private var conteneurImages:Sprite;
private var traitHaut:Shape;
private var traitBas:Shape;
private var messageChargement:TextField
private const ECART_VIGNETTES:int = 10;
private var timer:Timer;
private const PAS_DEPLACEMENT:int = 10;


public function Diaporama()
{
addUI();//ajout de l'interface
loadImagesPath();//chargement des chemins des images
}





//Interface managment
private function addUI():void
{
//Instances
nextButton = new NextButton();
previousButton = new PreviousButton();
conteneurVignettes = new Sprite();
masqueVignettes = new Sprite();
conteneurImages = new Sprite();
traitHaut = new Shape();
traitBas = new Shape();
timer = new Timer(50);

//Nom des boutons
nextButton.name = "nextButton";
previousButton.name = "previousButton";


//Positionnement et dessin
nextButton.x = stage.stageWidth - (nextButton.width + 5);
previousButton.x = 5;
nextButton.y = previousButton.y = stage.stageHeight - (nextButton.height + 5);

//variable locales
var distanceEntreBoutons:Number = Point.distance(new Point(previousButton.getBounds(this).right, previousButton.y), new Point(nextButton.x, previousButton.y));

traitHaut.graphics.lineStyle(1, 0x333333);//epaisseur et couleur du trait
traitHaut.graphics.moveTo(0, 0);//coordonnées de départ du trait
traitHaut.graphics.lineTo(distanceEntreBoutons, 0);//coordonnées de fin du trait
traitHaut.x = previousButton.getBounds(this).right;
traitHaut.y = previousButton.y;
traitBas.graphics.lineStyle(1, 0x333333);//epaisseur et couleur du trait
traitBas.graphics.moveTo(0, 0);//coordonnées de départ du trait
traitBas.graphics.lineTo(distanceEntreBoutons, 0);//coordonnées de fin du trait
traitBas.x = traitHaut.x;
traitBas.y = previousButton.getBounds(this).bottom - 1;
masqueVignettes.graphics.beginFill(0xFFFFFF);//couleur du masque (elle n'a aucune importance puique l'objet va servir de masque)
masqueVignettes.graphics.drawRect(0, 0, distanceEntreBoutons, previousButton.height);//dessin du rectangle
conteneurVignettes.x = masqueVignettes.x = traitHaut.x;//Positionnement en x du conteneur et du masque
conteneurVignettes.y = masqueVignettes.y = traitHaut.y;//Positionnement en y du conteneur et du masque
conteneurImages.x = (stage.stageWidth - conteneurImages.width) / 2;
conteneurImages.y = 10;

//masque du conteneur des vignettes
conteneurVignettes.mask = masqueVignettes;

//affichage de l'interface
addChild(nextButton);
addChild(previousButton);
addChild(conteneurVignettes);
addChild(conteneurImages);
addChild(traitHaut);
addChild(traitBas);
}




//XML loading
private function loadImagesPath():void
{
var urlLoader:URLLoader = new URLLoader(); //conteneur de chargement du fichier XML
urlLoader.addEventListener(Event.COMPLETE, loadImagesPathCompleted); //abonnement à l'événement Event.COMPLETE
urlLoader.addEventListener(IOErrorEvent.IO_ERROR, loadImagesPathIoError); //abonnement à l'événement IOErrorEvent.IO_ERROR
urlLoader.load(new URLRequest("xml/diaporama.xml")); //chargement du fichier XML
}

private function loadImagesPathIoError(evt:IOErrorEvent):void
{
//Rectangle de couleur noir couvrant la totalité de la scène
var cache:Shape = new Shape();
cache.graphics.beginFill(0x000000);
cache.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(cache);
//Message d'erreur
var message:TextField = new TextField();
message.autoSize = TextFieldAutoSize.LEFT;
message.defaultTextFormat = new TextFormat("Verdana", 28);
message.text = "Une erreur de chargement a eu lieu !";
message.textColor = 0xFFFFFF;
message.x = (stage.stageWidth - message.textWidth) / 2;
message.y = (stage.stageHeight - message.textHeight) / 2;
addChild(message);
}




//thumbnails creation
private function loadImagesPathCompleted(evt:Event):void
{
//Message de chargement
messageChargement = new TextField();
messageChargement.autoSize = TextFieldAutoSize.LEFT; //redimensionnement automatique à partir de la gauche
messageChargement.selectable = false; //Le texte n'est pas sélectionnable
messageChargement.text = "Chargement en cours..."; //Message indiquant un chargement en cours
messageChargement.x = (traitHaut.width - messageChargement.textWidth) / 2; // position x du message dans le conteneur
messageChargement.y = (nextButton.height - messageChargement.textHeight) / 2; // position y du message dans le conteneur
conteneurVignettes.addChild(messageChargement); // le message est ajouté dans le conteneur des vignettes

// Flux XML
var xml:XML = new XML(evt.target.data); //Récupération du flux XML
var xmlList:XMLList = xml.elements(); //Récupération de la liste des noeuds image
for each(var image:XML in xmlList)
{
var loader:Loader = new Loader(); //conteneur pour chaque image
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadImageCompleted); //abonnement à l'événement Event.COMPLETE
//loader.load(new URLRequest(image.@chemin)); //chargement de l'image
loader.load(new URLRequest(image.@chemin)); //chargement de l'image
}
}


private function loadImageCompleted(evt:Event):void
{
if (conteneurVignettes.contains(messageChargement)) //si le conteneur de vignettes contient le message de chargement
{
conteneurVignettes.removeChild(messageChargement); //alors il est supprimé de l'interface
}

conteneurVignettes.addEventListener(Event.ADDED, imageAdded); //abonnement du conteneur des vignettes à l'événement Event.ADDED

var loader:Loader = evt.target.loader; //conteneur de l'image
var ratio:Number = loader.height / nextButton.height; //ratio pour le redimensionnement des images
loader.width /= ratio; //largeur de la vignette
loader.height /= ratio; //hauteur de la vignette
conteneurVignettes.addChild(loader); //ajout de la vignette dans le conteneur
}



//thumbnails position
private function imageAdded(evt:Event):void
{
var loader:Loader = evt.target as Loader; //la vignette qui est ajoutée
var conteneur:Sprite = evt.currentTarget as Sprite; //le conteneur des vignettes
var index:int = conteneur.getChildIndex(loader); //l'index dans la liste d'affichage

if(index != 0) //si la vignette n'est pas la première
{
var previousX:Number = conteneur.getChildAt(index - 1).getBounds(conteneur).right; //coordonnée X du côtét droit de la vignette précédemment ajoutée
loader.x = previousX + ECART_VIGNETTES; //positionnement de la vignette 10 pixels après la vignette précédente
}
loader.addEventListener(MouseEvent.CLICK, vignetteClic); //abonnement à l'événement clic

//horizontal sliding
nextButton.addEventListener(MouseEvent.MOUSE_OVER, scrollNextButtonOver); //abonnement à l'événement MouseEvent.MOUSE_OVER
nextButton.addEventListener(MouseEvent.MOUSE_OUT, scrollNextButtonOut); //abonnement à l'événement MouseEvent.MOUSE_OUT
previousButton.addEventListener(MouseEvent.MOUSE_OVER, scrollPreviousButtonOver); //abonnement à l'événement MouseEvent.MOUSE_OVER
previousButton.addEventListener(MouseEvent.MOUSE_OUT, scrollPreviousButtonOut); //abonnement à l'événement MouseEvent.MOUSE_OUT
}


private function scrollNextButtonOver(evt:MouseEvent):void
{
timer.addEventListener(TimerEvent.TIMER, scrollNextTimer); //abonnement à l'événement TimerEvent.TIMER
timer.start(); //démarrage du timer
}

private function scrollPreviousButtonOver(evt:MouseEvent):void
{
timer.addEventListener(TimerEvent.TIMER, scrollPreviousTimer); //abonnement à l'événement TimerEvent.TIMER
timer.start(); //démarrage du timer
}
private function scrollNextButtonOut(evt:MouseEvent):void
{
timer.removeEventListener(TimerEvent.TIMER, scrollNextTimer); //annulation de l'abonnement à l'événement TimerEvent.TIMER
}

private function scrollPreviousButtonOut(evt:MouseEvent):void
{
timer.removeEventListener(TimerEvent.TIMER, scrollPreviousTimer); //annulation de l'abonnement à l'événement TimerEvent.TIMER
}

private function scrollNextTimer(evt:TimerEvent):void
{
if (conteneurVignettes.getBounds(this).right >= (masqueVignettes.getBounds(this).right + PAS_DEPLACEMENT))//si le bord droit du conteneur est positionné après le bord droit du masque
{
conteneurVignettes.x -= PAS_DEPLACEMENT; // le conteneur est déplacé vers la gauche
}
else
{
timer.removeEventListener(TimerEvent.TIMER, scrollNextTimer); //annulation de l'abonnement à l'événement TimerEvent.TIMER
}
}
private function scrollPreviousTimer(evt:TimerEvent):void
{
if (conteneurVignettes.x <= (masqueVignettes.x - PAS_DEPLACEMENT))//si le bord gauche du conteneur est positionné avant le bord gauche du masque
{
conteneurVignettes.x += PAS_DEPLACEMENT; // le conteneur est déplacé vers la droite
}
else
{
timer.removeEventListener(TimerEvent.TIMER, scrollPreviousTimer); //annulation de l'abonnement à l'événement TimerEvent.TIMER
}
}



//Big size pict display
private function vignetteClic(evt:MouseEvent):void
{
var image:Bitmap = (evt.currentTarget as Loader).contentLoaderInfo.content as Bitmap; //image correspondant à la vignette cliquée
var pixels:BitmapData = image.bitmapData; // pixels de l'image
var newPixels:BitmapData = new BitmapData(pixels.width, pixels.height); //conteneur de la copie des pixels
newPixels.copyPixels(pixels, new Rectangle(0, 0, pixels.width, pixels.height), new Point(0,0)); //copie des pixels
var newImage:Bitmap = new Bitmap(newPixels); //Image en taille réelle
if (conteneurImages.numChildren != 0) //si le conteneur contient déjà une image
{
conteneurImages.removeChildAt(0);// l'image est supprimée de la liste d'affichage
}
conteneurImages.addChild(newImage); //la nouvelle image est ajoutée à la liste d'affichage du conteneur
conteneurImages.x = (stage.stageWidth - conteneurImages.width) / 2; //positionnement du conteneur
conteneurImages.y = 10;
}

}
}
Si vous avez une idée de ce qui foire (ou qui manque), merci de m'aider.
J'ai aussi mis le zip du dossier de travail en pièce jointe.

Merci,
Cyril.

Fichier(s) joint(s)



#2 la pieuvre

  • Honoris
  • PipPipPipPipPipPipPipPip
  • 3055 messages

Posté 21 November 2008 - 18:24 PM

salut, tiré direct de l'aide :

1088 Le marquage du document qui suit l'élément racine doit être bien constitué. Voici des causes possibles de cette erreur :

* Analyse d'un objet de style XMLList en tant que XML
* Chaînes déséquilibrées
(F1 est ton amie wink.gif)

#3 cyrilou

    Ceinture Marron

  • Members
  • PipPipPipPipPipPip
  • 125 messages

Posté 21 November 2008 - 18:41 PM

Merci pour ta réponse rapide mais toujours aucune idée de comment régler ça...

#4 dada

  • Honoris
  • PipPipPipPipPipPipPipPip
  • 8510 messages

Posté 21 November 2008 - 18:43 PM

C'est une erreur dans le fichier XML, il est mal formé.

#5 cyrilou

    Ceinture Marron

  • Members
  • PipPipPipPipPipPip
  • 125 messages

Posté 21 November 2008 - 18:48 PM

oh l'erreur de débile mental... il manquait le "<" à la premiere ligne du xml!! le boulet...
bon ben la j'ai honte mais suis quand meme content parce que oui, ça marche mieux du coup maintenant...
merci Dada et bien vu!
Cyril.

#6 jstgeorge5

    Ceinture Blanche

  • Members
  • Pip
  • 1 messages

Posté 22 November 2008 - 15:53 PM

Je rebondis sur la discussion, j'ai également fait le même diaporama qui marche sans souci, par contre je n'arrive pas à l'importer dans le site duquel il est censé faire partie. Je l'importe avec l'UILoader du menu composants et j'ai le message d'erreur suivant :


TypeError: Error #1009: Il est impossible d'accéder à la propriété ou à la méthode d'une référence d'objet nul.
at Diaporama/::addUI()
at Diaporama$iinit()



1 utilisateur(s) li(sen)t ce sujet

0 membre(s), 1 invité(s), 0 utilisateur(s) anonyme(s)