Forums Développement Multimédia

Aller au contenu

Contenu de pol2095

Il y a 84 élément(s) pour pol2095 (recherche limitée depuis 28-January 18)


Filtrer par type de contenu

Voir pour ce membre


#1169632 Android Java vs Flash AS3

Posté par pol2095 sur 24 January 2018 - 21:28 PM in Développement Actionscript

Pour des accès particuliers à du matériel ou des couches soft, Adobe Air avec les extensions natives, ou Unity, voire Phonegap peuvent y accéder.
Angular et son data binding sont très gourmands en mémoire vive.
OpenFl est bien pour porter des jeux as3/Air vers le web.



#1169634 Code pour plusieurs clips

Posté par pol2095 sur 26 January 2018 - 21:41 PM in Développement Actionscript

Tu peux étendre flash.display.MovieClip, créer dans cette classe les variables qui sont propres à tes MovieClips (currentStep, nextX, ...)
Tu places tes clips dans un Array.

Tu places une boucle dans tes écouteurs.




#1169644 Code pour plusieurs clips

Posté par pol2095 sur 03 February 2018 - 19:11 PM in Développement Actionscript

Il doit te donner le numéro de la ligne où se trouve l'erreur ?

as-tu créé une classe comme ceci :

package com.display
{
        import flash.display.MovieClip;
 
        public class MyClip extends MovieClip
        {
                public var currentStep :Number  = this.x;
         
                ...
        }
}

et cocher la case "Expoter pour actionscript" dans les propriétés de ton MovieClip, puis modifier la classe de base "flash.display.MovieClip" par "com.display.MyClip"

ça sera plus simple par la suite



#1169646 Code pour plusieurs clips

Posté par pol2095 sur 04 February 2018 - 00:11 AM in Développement Actionscript

Tu crées dans le dossier où se trouve ton fla un dossier "com", dedans tu crées un dossier "display", dedans tu crées un fichier "MyClip.as".
ensuite tu colles le code que je t'ai donné.
par exemple pour accéder à currentStep pour chaque clip que tu utilises dans ton fla
tab_pages[i].currentStep

si tu places ton code de départ dans cette classe, ça devrait fonctionner sans avoir besoin d'utiliser de boucles, il faudra remplacer "page_slider" par "this"



#1169648 Code pour plusieurs clips

Posté par pol2095 sur 04 February 2018 - 11:01 AM in Développement Actionscript

tu as bien créé les 2 dossiers "com" et "display" dans "com" ?

il faudrait voir l'arborescence de ton projet (dossiers et fichiers), il y a un pb, il ne trouve pas la classe



#1169651 Code pour plusieurs clips

Posté par pol2095 sur 04 February 2018 - 12:44 PM in Développement Actionscript

Ce n'est pas bon, fais une copie écran de ton explorateur de fichiers au niveau de ton projet.



#1169653 Code pour plusieurs clips

Posté par pol2095 sur 04 February 2018 - 13:29 PM in Développement Actionscript

Le fla, il est où ?



#1169656 Code pour plusieurs clips

Posté par pol2095 sur 04 February 2018 - 14:31 PM in Développement Actionscript

Joint une version allégée de ton dossier dans un zip pour tester



#1169657 Code pour plusieurs clips

Posté par pol2095 sur 04 February 2018 - 16:11 PM in Développement Actionscript

Regarde dans les propriétés actionscript, il doit falloir renter un chemin de type "."



#1169660 Code pour plusieurs clips

Posté par pol2095 sur 04 February 2018 - 18:35 PM in Développement Actionscript

Regarde si dans Fichier > Paramètres avancés d'ActionScript 3.0 > onglet chemin source > il y a un dossier nommé "."

au début de ta classe il y a une erreur, c'est "import flash.display.MovieClip;" et non "import com.display.MyClip;", on va étendre

flash.display.MovieClip




#1169662 Code pour plusieurs clips

Posté par pol2095 sur 04 February 2018 - 20:42 PM in Développement Actionscript

Non, le point c'est bon, il ne faut rien toucher.

il faut juste remplacer dans ta classe "import com.display.MyClip;" par "import flash.display.MovieClip;"


ça drevrait corriger cette erreur

Citation

1017 : La définition de la classe de base MovieClip est introuvable.

5000 : La classe 'com.display.MyClip' doit être une sous-classe de 'flash.display.MovieClip', puisqu'elle est liée à un symbole de bibliothèque du type correspondant


j'ai remis en forme ton code

package com.display
{
  import flash.display.MovieClip;
 
  public class MyClip extends MovieClip
  {
    public var currentStep: Number;
    public var step: Number = 330;
    public var max: Number = 0;
    public var min: Number = -660;
    public var distMin: Number = 15;
    public var nextX: Number;
    public var startX: Number;
    public var offsetX: Number;
    public var moving: Boolean = false;
    public var smooth: Number = 0.30;
    public var mouseIsUp: Boolean = true;
   
    public function MyClip()
    {
          this.x = 0;
          currentStep = this.x;
          nextX = currentStep;
          this.addEventListener(MouseEvent.MOUSE_DOWN, onDown);
    }
   
    public function onDown(e: MouseEvent): void
    {
          offsetX = this.mouseX;
          startX = mouseX;
          moving = true;
          mouseIsUp = false;
          if (!hasEventListener(Event.ENTER_FRAME)) addEventListener(Event.ENTER_FRAME, update);
          stage.addEventListener(MouseEvent.MOUSE_MOVE, onMove);
          stage.addEventListener(MouseEvent.MOUSE_UP, onUp);
    }
   
    public function onUp(e: MouseEvent): void
    {
          mouseIsUp = true;
          var dx: Number = mouseX - startX;
          if (dx < -distMin)
          {
            currentStep -= step;
            if (currentStep < min) currentStep = min;
          }
          else if (dx > distMin)
          {
            currentStep += step;
            if (currentStep > max) currentStep = max;
          }
          nextX = currentStep;
          stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMove);
          stage.removeEventListener(MouseEvent.MOUSE_UP, onUp);
    }
   
    public function onMove(e: MouseEvent): void
    {
          nextX = mouseX - offsetX;
    }
   
    public function update(e: Event): void
    {
          if (moving)
          {
            this.x -= (this.x - nextX) * smooth;
            if (mouseIsUp && Math.abs(this.x - nextX) < 1)
            {
                  this.x = nextX;
                  moving = false;
                  removeEventListener(Event.ENTER_FRAME, update);
            }
          }
    }
  }
}



#1169664 Code pour plusieurs clips

Posté par pol2095 sur 05 February 2018 - 23:11 PM in Développement Actionscript

c'est bizarre, une erreur à la ligne 97, mais la classe ne fait pas 97 lignes ?



#1169666 Code pour plusieurs clips

Posté par pol2095 sur 06 February 2018 - 09:37 AM in Développement Actionscript

Tu dois avoir du code qui traine sur la frame1 dans ton MovieCip peut-être ?



#1169668 Code pour plusieurs clips

Posté par pol2095 sur 06 February 2018 - 20:28 PM in Développement Actionscript

ça doit fonctionner avec ton code tel quel

peut-être des soucis avec mouseX qui sera relatif à ton clip et non au stage, à vérifier



#1169689 Cibler un élément se trouvant dans une nativewindow

Posté par pol2095 sur 19 February 2018 - 18:22 PM in RIA: Flash Builder & AIR

Ce n'est pas si simple, essaie

var main:Object = NativeApplication.nativeApplication.openedWindows[1].stage.getChildAt(0);
 



#1169691 Cibler un élément se trouvant dans une nativewindow

Posté par pol2095 sur 20 February 2018 - 09:50 AM in RIA: Flash Builder & AIR

En créant une variable Object, qui n'est pas typé, tu ne devrais pas avoir d'erreur.

var main:Object = NativeApplication.nativeApplication.openedWindows[1].stage.getChildAt(0);

trace(main.textField);



#1169696 [Résolu] - Rotation vidéo via NetStream

Posté par pol2095 sur 21 February 2018 - 16:33 PM in Développement Actionscript

C'est bizarre ce bug.
Il faudrait essayer de déactiver "disableMediaCodec" (true) dans le descripteur de l'application ou d'utilser la classe flash.media.StageVideo



#1169698 [Résolu] - Rotation vidéo via NetStream

Posté par pol2095 sur 21 February 2018 - 19:01 PM in Développement Actionscript

Il faut rajouter dans le fichier "application.xml" de ton projet air <disableMediaCodec>true</disableMediaCodec>

où as-tu vu qu'on ne pouvait pas appliquer de rotation avec StageVideo ?



#1169700 [Résolu] - Rotation vidéo via NetStream

Posté par pol2095 sur 21 February 2018 - 21:19 PM in Développement Actionscript

Ta version d'Adobe Air est trop ancienne.

Autre possibilité flash.display3D.textures.VideoTexture mais ça nécessite d'utiliser Stage3D, la vidéo peut pivoter en 3D, mais ça ne peut pas s'utiliser avec la display list classique.



#1169702 [Résolu] - Rotation vidéo via NetStream

Posté par pol2095 sur 22 February 2018 - 19:18 PM in Développement Actionscript

Regarde dans les variables d'environnement de Windows, il doit y avoir un chemin vers Air SDK 23, modifie le.



#1169704 Cibler un élément se trouvant dans une nativewindow

Posté par pol2095 sur 23 February 2018 - 11:30 AM in RIA: Flash Builder & AIR

La classe principale c'est toujours "stage.getChildAt(0)"



#1169706 [Résolu] - Rotation vidéo via NetStream

Posté par pol2095 sur 24 February 2018 - 19:53 PM in Développement Actionscript

C'est sur Android ?



#1169708 [Résolu] - Rotation vidéo via NetStream

Posté par pol2095 sur 24 February 2018 - 20:46 PM in Développement Actionscript

essaie ce code avec Starling (télécharge le swc)

Main.as
package
{
        import com.VideoT;
 
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.display.StageAlign;
        import flash.display.StageScaleMode;
 
        import starling.core.Starling;
 
        public class Main extends Sprite
        {
                private var _starling:Starling = null;
         
                public function Main()
                {
                        stage.scaleMode = StageScaleMode.NO_SCALE;
                        stage.align = StageAlign.TOP_LEFT;
                 
                        addEventListener(Event.ADDED_TO_STAGE, init);
                }
         
                public function init(event:Event):void{
                        removeEventListener(Event.ADDED_TO_STAGE, init);
                 
                        _starling = new Starling(VideoT, stage);
                        _starling.antiAliasing = 1;
                        _starling.start();
                }
        }
}

com.VideoT.as
package com
{
        import flash.net.NetConnection;
        import flash.net.NetStream;
        import starling.core.Starling;
        import starling.display.Image;
        import starling.display.Sprite;
        import starling.events.Event;
        import flash.events.NetStatusEvent;
        import starling.textures.Texture;
        import starling.utils.deg2rad;

        public class VideoT extends Sprite
        {
                private var nc:NetConnection;
                private var ns:NetStream;
                private var texture:Texture;

                public function VideoT()
                {
                        addEventListener(Event.ADDED_TO_STAGE, init);
                }

                private function init(e:Event):void
                {
                        removeEventListener(Event.ADDED_TO_STAGE, init);
                 
                        this.rotation = deg2rad( 10 );
                        core();
                }

                private function core():void
                {
                        nc = new NetConnection();
                        nc.connect(null);

                        ns = new NetStream(nc);
                        ns.play("ta_vidéo");
                        ns.addEventListener(NetStatusEvent.NET_STATUS, netstat);
                       
                        texture = Texture.fromNetStream(ns, 1, function():void
                        {
                                addChild(new Image(texture));
                        });
                        texture.root.onRestore = videoTexture_onRestore;
                }
         
                private function videoTexture_onRestore():void
                {
                        texture.root.attachNetStream(ns, function():void
                        {
                                addChild(new Image(texture));
                        });
                }
         
                private function netstat(stats:NetStatusEvent):void
                {
                          trace(stats.info.code);
                }
        }
}



#1169738 Heures d'ouverture

Posté par pol2095 sur 09 March 2018 - 09:41 AM in Animer avec Flash

L'innovation est à proscrire sur le web de nos jours, même en javascript tu vas perdre des points en SEO, le javascript ou la balise canvas ne sont pas lus par les moteurs de recherche.



#1169745 Effet dynamique pour slider un clip

Posté par pol2095 sur 12 March 2018 - 09:27 AM in Développement Actionscript

ton code est illisible, essaie de l'indenter avec des espaces plutôt que des tabulations (il serait bien que ce site supporte les tabulations pour le code).
essaie de ne pas mettre des fonctions dans des fonctions.



#1169770 Probleme avec la rotationY appliquée à un movieclip

Posté par pol2095 sur 17 March 2018 - 12:35 PM in Discussions

Flash mesure le cadre de ton MovieClip, donc en pivotant le cadre est plus grand.



#1169772 Probleme avec la rotationY appliquée à un movieclip

Posté par pol2095 sur 17 March 2018 - 16:43 PM in Discussions

un exemple, prenons un carré 100x100

Image IPB

avec une rotation de 20°, le cadre ne fait plus 100x100 mais 130x130

Image IPB

après si tu utilises une rotation 3D, s'ajoute aussi le pb du positionnement de la caméra...



#1169784 Intégration d'une typo à une application Air

Posté par pol2095 sur 27 March 2018 - 20:59 PM in Discussions

Tu utilises un champs de texte TLF ou classique ?

il nous faut un peu de code.



#1169788 Intégration d'une typo à une application Air

Posté par pol2095 sur 28 March 2018 - 11:05 AM in Discussions

Du moment où tu fais une application AIR, il n'y a aucun pb avec la mort de Flash. De toute façon les navigateurs sont en perdition par rapport aux applications (trop lourd, trop lent, pas d'accès aux fonctions natives des smartphones, pas adapté pour des projets complexes...)



#1169807 Modification du son avec animate

Posté par pol2095 sur 10 April 2018 - 19:56 PM in Discussions

peut-être une idée ici



#1169853 Lancement d'Excel en AS3

Posté par pol2095 sur 25 April 2018 - 16:33 PM in Développement Actionscript

Regarde du côté de File.openWithDefaultApplication(), il me semble que cette méthode ne fonctionne que sous Windows et Mac.



#1169855 Ecouteurs d'evenement sur changement d'etat

Posté par pol2095 sur 25 April 2018 - 18:19 PM in Discussions

la doc d'Abobe est bien faite.



#1169872 Fonction zoom sur sur adobe Reader

Posté par pol2095 sur 10 May 2018 - 20:17 PM in Discussions

C'est faisable mais pas si simple, je l'ai fait avec Starling/Feathers, si ça peut t'aider ici (version pour mobile), Starling gère le point d'ancrage, pas la classique display list, il va falloir placer ton MovieClip ou ton image dans un Sprite.



#1169877 Fonction zoom sur sur adobe Reader

Posté par pol2095 sur 11 May 2018 - 23:08 PM in Discussions

essaie ce code

private function zoomImage(e:MouseEvent):void
{
    var zoomAmount:Number = 0.1;
    if( e.delta < 0 ) zoomAmount *= -1;
   
    var x:int = e.currentTarget.mouseX;
    var y:int = e.currentTarget.mouseY;
    e.currentTarget.scaleX += zoomAmount;
    e.currentTarget.scaleY += zoomAmount;
    e.currentTarget.x -= x * zoomAmount;
    e.currentTarget.y -= y * zoomAmount;
}



#1169930 fonction drag and drop pour Android

Posté par pol2095 sur 25 June 2018 - 21:54 PM in Discussions

le 3ème paramètres est facultatif, regarde la doc

import flash.events.TouchEvent;
import flash.ui.Multitouch;
import flash.ui.MultitouchInputMode;

Multitouch.inputMode = MultitouchInputMode.TOUCH_POINT;

Plan.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
Plan.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);

function onTouchBegin(event:TouchEvent):void
{
        event.target.startTouchDrag(event.touchPointID);
}
 
function onTouchEnd(event:TouchEvent):void
{
        event.target.stopTouchDrag(event.touchPointID);
}



#1169935 fonction drag and drop pour Android

Posté par pol2095 sur 27 June 2018 - 08:12 AM in Discussions

Je ne pense pas qu'on puisse utiliser les 2 en même temps, il faudrait recréer "GESTURE_ZOOM" avec MultitouchInputMode.TOUCH_POINT.



#1169939 fonction drag and drop pour Android

Posté par pol2095 sur 28 June 2018 - 17:04 PM in Discussions

J'ai réalisé quelque chose de similaire avec Starling qui utilise MultitouchInputMode.TOUCH_POINT et pas les fonctions prédifinies d'Adobe.



#1169941 fonction drag and drop pour Android

Posté par pol2095 sur 28 June 2018 - 19:47 PM in Discussions

si tu veux déplacer un object avec "MultitouchInputMode.GESTURE" il faut utiliser "GESTURE_PAN" (avec 2 doigts)

Multitouch.inputMode = MultitouchInputMode.GESTURE;

Plan.addEventListener(TransformGestureEvent.GESTURE_PAN, panHandler);

function panHandler(event:TransformGestureEvent):void
{
event.currentTarget.x += event.offsetX;
event.currentTarget.y += event.offsetY;
}



#1169942 fonction drag and drop pour Android

Posté par pol2095 sur 30 June 2018 - 07:47 AM in Discussions

Une autre façon de faire est d'utiliser "MultitouchInputMode.TOUCH_POINT", voilà un exemple qui recréer "
GESTURE_ZOOM" avec un drag à un doigt

package
{
        import com.MySprite;
        import flash.display.Bitmap;
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.ui.Multitouch;
        import flash.ui.MultitouchInputMode;

        public class Main extends Sprite
        {
                [Embed(source = "./Image.jpg")]
                private static const MyImage:Class;
       
                public function Main()
                {
                        this.addEventListener(Event.ADDED_TO_STAGE, addedToStageHandler);
                }
       
                private function addedToStageHandler(event:Event):void
                {
                        this.removeEventListener(Event.ADDED_TO_STAGE, addedToStageHandler);
               
                        Multitouch.inputMode = MultitouchInputMode.TOUCH_POINT;
               
                        var mySprite:MySprite = new MySprite();
                        this.addChild(mySprite);
                        var myImage:Bitmap = new MyImage();
                        myImage.scaleX = myImage.scaleY = 0.2;
                        mySprite.addChild( myImage );
                }
        }
}

package com
{
        import flash.display.DisplayObject;
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.TouchEvent;
        import flash.geom.Point;
        import flash.geom.Rectangle;

        public class MySprite extends Sprite
        {
                private var touches:Vector.<TouchEvent> = new <TouchEvent>[];
                private var touchPointID:int = -1;
                private var previousPosA:Point;
                private var previousPosB:Point;
                private var touchesContains:Vector.<Boolean> = new <Boolean>[];
       
                public function MySprite()
                {
                        this.addEventListener(Event.ADDED_TO_STAGE, addedToStageHandler);
                }
       
                private function addedToStageHandler(event:Event):void
                {
                        this.removeEventListener(Event.ADDED_TO_STAGE, addedToStageHandler);
               
                        stage.addEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
                        stage.addEventListener(TouchEvent.TOUCH_END, onTouchEnd);
                }
       
                private function onTouchBegin(event:TouchEvent):void
                {
                        touches.push( event );
                        touchesContains.push( this.contains( event.target as DisplayObject ) );
                        if( touches.length == 1 )
                        {
                                if( this.contains( event.target as DisplayObject ) )
                                {
                                        touchPointID = event.touchPointID;
                                        this.startTouchDrag(event.touchPointID);
                                }
                        }
                        else if( touchPointID != -1 )
                        {
                                this.stopTouchDrag(touchPointID);
                                touchPointID = -1;
                        }
               
                        if( touches.length == 1 )
                        {
                                previousPosA  = new Point( event.stageX, event.stageY );
                        }
                        else if( touches.length == 2 )
                        {
                                previousPosB  = new Point( event.stageX, event.stageY );
                                stage.addEventListener(TouchEvent.TOUCH_MOVE, onTouchMove);
                        }
                }
       
                private function onTouchMove(event:TouchEvent):void
                {
                        if( touches.length == 2 )
                        {
                                var index:int = touchIndex( event );
                                touchesContains[ index ] = this.contains( event.target as DisplayObject );
                       
                                var currentPosA:Point = index == 0 ? new Point( event.stageX, event.stageY ) : previousPosA.clone();
                                var currentPosB:Point = index == 1 ? new Point( event.stageX, event.stageY ) : previousPosB.clone();
                       
                                if( touchesContains[0] || touchesContains[1] )
                                {
                                        var currentVector:Point  = currentPosA.subtract(currentPosB);
                                        var previousVector:Point = previousPosA.subtract(previousPosB);
                               
                                        var sizeDiff:Number = currentVector.length / previousVector.length;
                               
                                        if( Math.abs( sizeDiff - 1 ) > 0.01 ) zoomImage( sizeDiff - 1, midPoint( currentPosA, currentPosB ) );
                                }
                                previousPosA  = currentPosA.clone();
                                previousPosB  = currentPosB.clone();
                        }
                }
       
                private function zoomImage(zoomAmount:Number, midPoint:Point):void
                {
                        zoomAmount *= 2;
                        if( this.scaleX + zoomAmount < 0.8 ) zoomAmount = 0.8 - this.scaleX;
                        var local:Point = this.globalToLocal( midPoint );
                        var x:Number = local.x;
                        var y:Number = local.y;
                        this.scaleX += zoomAmount;
                        this.scaleY += zoomAmount;
                        this.x -= x * zoomAmount;
                        this.y -= y * zoomAmount;
                }
         
                private function onTouchEnd(event:TouchEvent):void
                {
                        var index:int = touchIndex( event );
                        touches.splice( index, 1 );
                        touchesContains.splice( index, 1 );
                        if( touches.length == 1 )
                        {
                                if( index == 0 ) previousPosA = previousPosB.clone();
                                stage.removeEventListener(TouchEvent.TOUCH_MOVE, onTouchMove);
                        }
                        if( touchPointID != -1 )
                        {
                                this.stopTouchDrag(touchPointID);
                                touchPointID = -1;
                        }
                }
       
                private function touchIndex(event:TouchEvent):int
                {
                        for(var i:int = 0; i < touches.length; i++)
                        {
                                if( touches[i].touchPointID == event.touchPointID )
                                {
                                        return i;
                                }
                        }
                        return -1;
                }
       
                private function midPoint(currentPosA:Point, currentPosB:Point):Point
                {
                        var midPoint:Point = Point.interpolate(currentPosA, currentPosB, 0.5);
                        var rect:Rectangle = this.getRect( stage );
               
                        if( midPoint.x < rect.x )
                        {
                                midPoint.x = rect.x;
                        }
                        else if( midPoint.x > rect.x + rect.width )
                        {
                                midPoint.x = rect.x + rect.width;
                        }
               
                        if( midPoint.y < rect.y )
                        {
                                midPoint.y = rect.y;
                        }
                        else if( midPoint.y > rect.y + rect.height )
                        {
                                midPoint.y = rect.y + rect.height;
                        }
               
                        return midPoint;
                }
       
                public function dispose():void
                {
                        stage.removeEventListener(TouchEvent.TOUCH_BEGIN, onTouchBegin);
                        stage.removeEventListener(TouchEvent.TOUCH_END, onTouchEnd);
                        touches = null;
                        touchesContains = null;
                }
        }
}

;-)



#1169946 Vérifier si le Wifi ou 3G-4G sont activés

Posté par pol2095 sur 02 July 2018 - 22:06 PM in Développement Actionscript

regarde ce lien



#1169949 Création de fichier AS3

Posté par pol2095 sur 03 July 2018 - 12:47 PM in Discussions

La classe File est faite pour ça, mais ne fonctionne qu'avec Air.



#1169951 Création de fichier AS3

Posté par pol2095 sur 03 July 2018 - 16:16 PM in Discussions

Pourquoi ne pas utiliser "SharedObject" ?



#1169954 Vérifier si le Wifi ou 3G-4G sont activés

Posté par pol2095 sur 03 July 2018 - 18:25 PM in Développement Actionscript

Non, j'ai testé avec Air 30, ça fonctionne sans rien ajouter, il faut créer un projet Air et non Flash.



#1169963 fonction drag and drop pour Android

Posté par pol2095 sur 12 July 2018 - 08:20 AM in Discussions

As-tu tester le code plus haut ?

pour le scroll de la souris
sprite.addEventListener(MouseEvent.MOUSE_WHEEL, zoomImage);

function zoomImage(event:MouseEvent):void
{
        var zoomAmount:Number = 0.1;
 
        if( event.delta < 0 ) zoomAmount *= -1;
        var x:int = sprite.mouseX;
        var y:int = sprite.mouseY;
        sprite.scaleX += zoomAmount;
        sprite.scaleY += zoomAmount;
        sprite.x -= x * zoomAmount;
        sprite.y -= y * zoomAmount;
}



#1170002 fonction drag and drop pour Android

Posté par pol2095 sur 23 August 2018 - 15:52 PM in Discussions

Félicitations

Regarde la classe Tween pour les effets



#1170073 ActionScript 3.0 : nom de variable dynamique

Posté par pol2095 sur 22 October 2018 - 14:34 PM in Développement Actionscript

...



#1170090 Erreur "aatp tool"

Posté par pol2095 sur 13 November 2018 - 14:08 PM in Développement Actionscript

Quelle version de Air utilises-tu ? c'est une erreur du packager d'images pour Android.



#1170142 Développer avec Adobe Flash

Posté par pol2095 sur 16 December 2018 - 20:32 PM in Développement Actionscript

Il y a des avantages et des inconvénients, quel genre d'applications ?
Pour ce qui est des performances, flash est bien optimisé pour l'affichage, as3 est plus lent que Java pour de gros calculs.
Flash n'a pas accès directement à beaucoup de fonctions natives, il faudra alors créer des Air Natives Extensions (c'est du natif).
Par contre une application conçu avec Air pourra fonctionner sur iOS, Windows, Mac avec quelques ajustements, alors qu'il faudra tout reprendre à zéro avec une app native.
Avec Flash, si tu utilises la Display List classique ou Starling (Stage3D), les performances sont différentes, avec Starling mes jeux tournent à 60 fps sans problème.

Pour le poids de l'application, étant donné que les app Air intègre le runtime, l'app sera plus lourde qu'une app native mais l'utilisateur ne verra pas si ton app est native ou pas.



#1170149 Exporter des données via une application

Posté par pol2095 sur 17 December 2018 - 22:56 PM in Développement Actionscript

Il est possible d'enregistrer un fichier avec la classe File sur la tablette, ou envoyer des données avec URLLoader et la méthode POST vers PHP par exemple (puis avec PHP, tu peux créer un fichier texte sur le serveur, email)



#1170151 Exporter des données via une application

Posté par pol2095 sur 18 December 2018 - 20:34 PM in Développement Actionscript

regarde ce tuto http://as3adventure....lash-using.html




authorised training centre

Centre de Formation Mediabox - Adobe et Apple Authorised Training Center.

Déclaré auprès de la Direction du Travail et de la Formation Professionnelle

Mediabox : SARL au capital de 62.000€ - Numéro d'activité : 11 75 44555 75 - SIRET : 49371646800035

MEDIABOX, 23, rue de Bruxelles, 75009 PARIS

FFP